mask

mask(Null, String | Number | PathElement): Any

mask を null 値に使用できるようにするヘルパー関数。

mask(Any, PathElement): Any

この mask 関数は、指定された条件に一致するすべての単純要素を置き換えます。

単純要素に子要素はありません。また、単純要素をオブジェクトまたは配列にすることはできません。

パラメーター

名前説明

名前	説明
`value`	マスクで使用する値。値には任意の DataWeave 型を使用できます。
`selector`	`PathElement` セレクター。

value

マスクで使用する値。値には任意の DataWeave 型を使用できます。

selector

PathElement セレクター。

例

次の例は、オブジェクトの配列内の password 項目の値をマスクする方法を示しています。これは field("password") を使用して PathElement を返し、それを mask に渡します。with "" を使用して、マスクで使用する値 () を指定します。

ソース

%dw 2.0
output application/json
import * from dw::util::Values
---
[{name: "Peter Parker", password: "spiderman"}, {name: "Bruce Wayne", password: "batman"}] mask field("password") with "*****"

出力

[
   {
     "name": "Peter Parker",
     "password": "*****"
   },
   {
     "name": "Bruce Wayne",
     "password": "*****"
   }
 ]

mask(Any, String): Any

この mask 関数は、項目をその名前で選択します。

パラメーター

名前説明

名前	説明
`value`	マスクで使用する値。値には任意の DataWeave 型を使用できます。
`fieldName`	マスクする項目の名前を指定する文字列。

value

マスクで使用する値。値には任意の DataWeave 型を使用できます。

fieldName

マスクする項目の名前を指定する文字列。

例

次の例は、入力内の項目の名前を使用してマスクを実行する方法を示しています。この値を持つすべての項目の値を変更します。

ソース

%dw 2.0
output application/json
import * from dw::util::Values
---
[{name: "Peter Parker", password: "spiderman"}, {name: "Bruce Wayne", password: "batman"}] mask "password" with "*****"

出力

[
   {
     "name": "Peter Parker",
     "password": "*****"
   },
   {
     "name": "Bruce Wayne",
     "password": "*****"
   }
 ]

mask(Any, Number): Any

この mask 関数は、配列の要素をそのインデックスで選択します。

パラメーター

名前説明

名前	説明
`value`	マスクする値。値には任意の DataWeave 型を使用できます。
`index`	マスクするインデックス。インデックスは数値である必要があります。

value

マスクする値。値には任意の DataWeave 型を使用できます。

index

マスクするインデックス。インデックスは数値である必要があります。

例

次の例は、ネストされた配列内のすべての要素に対して mask がどのように動作するかを示しています。インデックス 1 の位置にある各要素の値を false に変更します。

ソース

%dw 2.0
output application/json
import * from dw::util::Values
---
[[123, true], [456, true]] mask 1 with false

出力

[
   [
     123,
     false
   ],
   [
     456,
     false
   ]
 ]